// 2018/08/18  ver. 1.0.1
#include "Stepper.h" //  ver1.1.3
#define STEPS 32     // Number of steps for one revolution of Internal shaft
                     // 2048 steps for one revolution of External shaft
                     // if 4096 steps required, change to "STEPS 64"
                     
volatile boolean TurnDetected;  // need volatile for Interrupts
volatile boolean rotationdirection;  // CW or CCW rotation

const int PinCLK=2;   // Generating interrupts using CLK signal
const int PinDT=3;    // Reading DT signal
const int PinSW=4;    // Reading Push Button switch
const int PinHiLoSW=5;   // Reading Speed(Step) Hi/Lo switch

int Speed;               // Step per one click
int Speedswposition=0;
int RotaryPosition=0;    // To store Stepper Motor Position
int PrevPosition;     // Previous Rotary position Value to check accuracy
int StepsToTake;      // How much to move Stepper

// Setup of proper sequencing for Motor Driver Pins In1, In2, In3, In4 in the sequence 1-3-2-4
Stepper small_stepper(STEPS, 8, 10, 9, 11);

// Interrupt routine runs if CLK goes from HIGH to LOW
void isr () 
{
  delay(1);  // delay for Debouncing
  if (digitalRead(PinCLK))
    rotationdirection= digitalRead(PinDT);
  else
    rotationdirection= !digitalRead(PinDT);
  TurnDetected = true;
}

void setup ()  
{
pinMode(PinCLK,INPUT);
//digitalWrite(PinCLK, HIGH);  // Pull-Up resistor  Please check the encoder PCB(PWB)
                               // If there is a resistor, comment out this line
pinMode(PinDT,INPUT);
//digitalWrite(PinDT, HIGH);   // Same as above
pinMode(PinSW,INPUT);
digitalWrite(PinSW, HIGH);     // Same as above
pinMode(PinHiLoSW,INPUT);
digitalWrite(PinHiLoSW, HIGH);   // Pull-Up resistor for step select switch
attachInterrupt (0,isr,FALLING); // interrupt 0 always connected to pin 2
}

void loop ()  
{
   if (!(digitalRead(PinHiLoSW))) // Change speed check. When PinHiLoSW is GND, step is large.
    {
     Speed=9; // "9" is 1.582deg per one click ( 9 x 0.1758deg)
    }
   else
    {
     Speed=3; // "3" is 0.527deg per one click ( 3 x 0.1758deg)
    }
  small_stepper.setSpeed(600);
   if (!(digitalRead(PinSW)))  // check if button is pressed
    {   
    if (RotaryPosition == 0)   // check if button was already pressed
      { 
      }
    else 
      {
          small_stepper.step(-(RotaryPosition*Speed));
          RotaryPosition=0; // Reset position to ZERO
      }
    }

  // Runs if rotation was detected
  if (TurnDetected)  
   {
    PrevPosition = RotaryPosition; // save previous position in variable
     if (rotationdirection)
       {
       RotaryPosition=RotaryPosition-1; // decrase Position by 1
       } 
     else
      {
       RotaryPosition=RotaryPosition+1; // increase Position by 1
      } 
          
    TurnDetected = false;  // do NOT repeat IF loop until new rotation detected    
    // Which direction to move Stepper motor
    if ((PrevPosition + 1) == RotaryPosition)  // Move motor CW
      {                              
        StepsToTake=Speed;
        small_stepper.step(StepsToTake);
      }
    if ((RotaryPosition + 1) == PrevPosition)  // Move motor CCW
      {                             
        StepsToTake=-Speed; // -50 to 2 slow rotation
        small_stepper.step(StepsToTake);
      } 
   }
  else // When rotary sw stop, turn off the motor after adequate delay time.
  {
     delay(30); // If delay time is small, torque is low. 
     digitalWrite(8, LOW);
     digitalWrite(9, LOW );
     digitalWrite(10, LOW);
     digitalWrite(11, LOW);
  }
}